方法 一：批处理开启组策略
dir 命令遍历系统盘 servicing 目录，查找有关组策略的配置包，找到后导入 txt 文件，调用 dism 命令安装组策略包
1. 复制如下代码到新建文本文档（任选其一）
————————————————Script 1————————————————
@echo off
pushd "%~dp0"
rem List all relevant .mum files and save to List.txt
dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum > List.txt
dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum >> List.txt
rem add each package from List.txt to DISM
for /f %%i in ('findstr /i . List.txt 2^>nul') do (
dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
)
pause
————————————————Script 2————————————————
@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
pushd "%~dp0"
dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum >List.txt
dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum >>List.txt
for /f %%i in ('findstr /i . List.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
pause
2. 将文本文档另存编码为 ANSI 的批处理文件 XXX.bat
极少数计算机另存编码为 UTF-8 运行异常。
3. 以管理员身份运行批处理文件
提示 “系统找不到指定的路径”，无需理会，等待批处理执行完毕即可。
方法 二：直接命令行开启组策略
以管理员身份打开 cmd，依次运行下面两行代码：
FOR %F IN ("%SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~*.mum") DO (DISM /Online /NoRestart /Add-Package:"%F")
验证
重启后，按组合键 Win + R，输入
gpedit.msc
